Fungsi LookUp Canggih Excel 2007/10 (1)

Jika Anda ingin mendapatkan yang terbaik dari rumus dan fungsi di Excel 2007/10, maka setiap Jumat, Anda akan mendapat berbagai tips kreatif & produktif di mana Anda dapat menggunakan Excel dengan lebih efektif dan dengan lebih mengangumkan. Nikmati tips minggu ini.

Baca juga Apa warna favorit Anda ketika membuat Grafik?

Menghitung PPh 21 Pribadi dengan fungsi VLOOKUP()

Fungsi VLOOKUP() merupakan fungsi pencarian yang sering digunakan dalam berbagai situasi seperti mencari informasi tarif pajak dalam satu tabel untuk digunakan untuk menghitung pajak penghasilan pasal 21.

Katakan Anda bekerja sebagai karyawan, status kawin dengan dua anak, dan penghasilan per bulannya Rp 10.000.000. Selain menerima gaji per bulan, Anda juga menerima tunjangan jabatan sebesar 10% dari gaji per bulan, premi asuransi kecelakaan kerja (0.25%) dan premi kematian (0.3%) dari program Jamsostek.

Perusahaan juga membayar program pensiun dan tunjangan hari tua (THT) untuk pegawainya dimana sebagian iuran pensiun dan THT ditanggung oleh pegawai masing-masing sebesar 4% dan 2%.

Maka penghitungan PPh 21 menjadi sebagai berikut.

Gaji bruto sebulan pada sel C7 dihitung dengan rumus berikut.


=SUM(C3:C6)

Biaya jabatan pada sel B9 dihitung dengan menggunakan fungsi IF() sebagai berikut. Jumlah biaya jabatan sebenarnya 5% dari adalah Rp 552.750, namun karena biaya jabatan maksimal yang diijinkan adalah Rp 500.000, maka fungsi IF() akan menampilkan angka Rp 500.000.


=IF(C7*5%>500000,500000,C7*5%)

Iuran Pensiun pada sel B10 dihitung berdasarkan persentase yang berlaku.


=C3*4%

Iuran THT pada sel B11 dihitung berdasarkan persentase yang berlaku.


=C3*2%

Penghasilan neto pada sel C14, dapat dihitung dengan rumus berikut.


=C7-B12

Penghasilan neto dalam 1 tahun pada sel C16 dihitung dengan mengkalikan penghasilan neto sebulan (sel C14) dengan 12 sebagai berikut.


=C14*12

Jumlah PTKP setahun pada sel C18 adalah Rp 21.120.000 karena berstatus menikah dengan dua anak dimana kode K/2 dimasukkan pada sel C1 dengan menggunakan fungsi VLOOKUP() seperti berikut.


=VLOOKUP(C1,Tarif!$A$3:$B$14,2,FALSE)

Tabel PTKP disimpan dalam lembar kerja terpisah, Tarif dalam buku kerja yang sama. Penyesuaian terhadap Penghasilan Tidak Kena Pajak yang berlaku efektif per 1 Januari 2009 dapat dibaca dari http://duniapajak.com/artikel-pajak/2011/tabel-tarif-pajak-dan-besarnya-ptkp-tahun-pajak-2010).

Penghasilan kena pajak setahun pada sel C19 dihitung dengan menggunakan fungsi IF() untuk menampilkan nilai 0 apabila PKP setahun kurang dari 0.


=IF(C16-C18>0,C16-C18,0)

Fungsi IF() bersarang pada sel C21 digunakan untuk menemukan tarif wajib pajak OP (tarif berlapis) berdasarkan nilai PKP.


=IF(C19<=50000000,C19*5%,
IF(AND(C19>50000000,C19<=250000000),(50000000*5%)+(C19-50000000)*15%,
IF(AND(C19>250000000,C19<=500000000),(50000000*5%)+(200000000*15%)+(C19-250000000)*25%,
(50000000*5%)+(200000000*15%)+(250000000*25%)+(C19-500000000)*30%)))

PPh 21 sebulan pada sel C23 dihitung dengan menggunakan fungsi IF() untuk menampilkan “Nihil” apabila tidak ada PPh 21 yang dikenakan.


=IF(C21/12>0,C21/12,”Nihil”)

Simak Lebih Banyak lagi Tips & Trik selanjutnya.
Buku “Fungsi LookUp Canggih Excel 2007/10” (Terbit Juli 2012)

http://www.elexmedia.co.id/buku/detail/9786020030456

Christopher Lee

Leave a Reply